::  It is recommended to test the script on a local machine for its purpose and effects. 
::  ManageEngine Desktop Central will not be responsible for any 
::  damage/loss to the data/setup based on the behavior of the script.

::  Description - Script to Disable Equation editor in Microsoft Office . 
::  Source: https://support.microsoft.com/en-in/help/4055535/how-to-disable-equation-editor-3-0
::  Configuration Type - Computer
::  ===========================================================================================================================
@echo off
set dis=0
reg Query "HKLM\Hardware\Description\System\CentralProcessor\0" | find /i "x86" > NUL && set OS=32BIT || set OS=64BIT
if %OS% == 32BIT (
goto checkOfcInsDir
) else (
goto checkOfcInsWow
)

:checkOfcInsDir
reg query HKLM\Software\Microsoft\Office > NUL
if %ERRORLEVEL% EQU 0 (
goto direct
) else (
goto ext
)

:checkOfcInsWow
reg query HKLM\Software\WOW6432Node\Microsoft\Office > NUL
if %ERRORLEVEL% EQU 0 (
goto wow6
) else (
goto checkOfcInsDir
)

:direct
set dis=1
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Office\Common\COM Compatibility\{0002CE02-0000-0000-C000-000000000046}" /v "Compatibility Flags" /d 00000400 /t REG_DWORD /f > NUL
reg delete "HKEY_CLASSES_ROOT\CLSID\{0002CE02-0000-0000-C000-000000000046}" /f 1>NUL 2>NUL
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Classes\Equation.3" /f 1>NUL 2>NUL
Echo Found  office installed - Equation editor disabled 
goto ext

:wow6
set dis=1
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\Office\Common\COM Compatibility\{0002CE02-0000-0000-C000-000000000046}" /v "Compatibility Flags" /d 00000400 /t REG_DWORD /f > NUL
reg delete "HKEY_CLASSES_ROOT\WOW6432Node\CLSID\{0002CE02-0000-0000-C000-000000000046}" /f 1>NUL 2>NUL
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Classes\Equation.3" /f 1>NUL 2>NUL
Echo Found  office installed - Equation editor disabled
goto checkOfcInsDir

:ext
if %dis% == 0 (
echo Microsoft Office not installed
exit 0
) else (
exit 0
)